[@闯关开始]
{
\ \
<当前元宝数量为：/SCOLOR=254>[<$GAMEGOLD>]个 <当前灵符数量为:/SCOLOR=254>[<$GAMEGIRD>]个\
<能来到这里，你果然智勇双全。/SCOLOR=253> \
<先看看我这里的宝物，只要打败所有怪物，宝物就归你了。/SCOLOR=250> \
<如果想到下一关，你可以使用1张灵符再过一次天关通道. /AUTOCOLOR=254,251,168,191,250,19,245,253>\
<如果不想使用灵符，那就靠实力打过去吧。 /SCOLOR=242>\
<天关有无数重，能过多少关就看你的勇气和毅力了。 /SCOLOR=254>\
<看看这里的宝物/@宝物> <挑战成功领取宝物/@领取> \
<返回天庭/@回天庭>
[@宝物]
#IF
check [152] 0
#act
MOVR M0 3
MOVR M1 5
MOVR M2 5
MOVR M3 1 8
MOVR M4 1 10
MOVR M5 5
GOTO @LOOK
#elseact
GOTO @LOOKS
[@LOOK]
#if
equal M0 0
#ACT
GetRandomText .\QuestDiary\魔王天关\经验.txt S78
GetRandomText .\QuestDiary\魔王天关\刷怪1.txt S64
MUL M9 <$STR(S78)> <$LEVEL>
#Say
<这次剿灭怪物你将获得经验:/SCOLOR=31>[<$STR(M9)>]\
#if
equal M0 1
#ACT
GetRandomText .\QuestDiary\魔王天关\01.txt S61
GetRandomText .\QuestDiary\魔王天关\刷怪1.txt S64
#Say
<这次剿灭怪物你将获得宝物：/SCOLOR=250>[<$STR(S61)>]\
#IF
equal M0 2
#ACT
GetRandomText .\QuestDiary\魔王天关\02.txt S61
GetRandomText .\QuestDiary\魔王天关\刷怪2.txt S64
#Say
<这次剿灭怪物你将获得宝物：/SCOLOR=242>[<$STR(S61)>]\
#IF
equal M1 2
#ACT
GetRandomText .\QuestDiary\魔王天关\03.txt S62
#SAY
<并且能发现其中的/SCOLOR=19>[<隐藏物品/SCOLOR=252>:<$STR(S62)>]\
#IF
equal M2 2
#ACT
GetRandomText .\QuestDiary\魔王天关\04.txt S63
#SAY
<而且会十分幸运的找到/SCOLOR=116>[<稀有物品/SCOLOR=253>:<$STR(S63)>]\
#IF
equal M5 2
#ACT
GetRandomText .\QuestDiary\魔王天关\Boss.txt S66
#IF
#ACT
set [152] 1
GetRandomText .\QuestDiary\魔王天关\刷怪1.txt S65
#say
\ \
<当然你必须消灭里面所有的: /AUTOCOLOR=254,251,168,191,250,19,245,253><$STR(S64)>:<$STR(M3)>‖<$STR(S65)>:<$STR(M4)>‖<$STR(S66)>\
<如果你觉得本关难度太高，或对宝藏不满意，/SCOLOR=239> \
<给我一张灵符，我就直接送您去下一关 /SCOLOR=249>\ \
<使用灵符进入下一关/@下一关> <接受挑战/@挑战>\
[@LOOKS]
#if
equal M0 0
#Say
<这次剿灭怪物你将获得经验:/SCOLOR=31>[<$STR(M9)>]\
#elseSay
<这次剿灭怪物你将获得宝物：/SCOLOR=250>[<$STR(S61)>]\
#IF
equal M1 2
#SAY
<并且能发现其中的/SCOLOR=19>[<隐藏物品/SCOLOR=252>:<$STR(S62)>]\
#IF
equal M2 2
#SAY
<而且会十分幸运的找到/SCOLOR=116>[<稀有物品/SCOLOR=253>:<$STR(S63)>]\
#IF
#SAY
\ \
<当然你必须消灭里面所有的：/SCOLOR=116><$STR(S64)>:<$STR(M3)>‖<$STR(S65)>:<$STR(M4)>‖BOSS:<$STR(S66)>\
<如果你觉得本关难度太高，或对宝藏不满意，/SCOLOR=215> \
<给我一张灵符，我就直接送您去下一关/SCOLOR=242>\ \
<使用灵符进入下一关/@下一关> <接受挑战/@挑战>\
[@挑战]
#if
check [150] 0
#act
set [150] 1
Param1 <$MAPCODE>
Param2 14
Param3 16
MonGen <$STR(S64)> <$STR(M3)> 10
MonGen <$STR(S65)> <$STR(M4)> 10
MonGen <$STR(S66)> 1 10
close
#ELSESAY
\ \
<你现在正在挑战呢。。。/SCOLOR=242>\ \<关闭/@exit>
[@领取]
#if
check [150] 0
#SAY
\ \
<你没有接受本关的挑战！/SCOLOR=250>\
<天关的宝藏只赠给有勇气的英雄。。。/SCOLOR=251>\ \<关闭/@exit>
#act
break
#if
CheckMapMonCount <$MAPCODE> > 0
#SAY
\ \
<怪物还没有清理干净呢。。。/SCOLOR=242>\ \<关闭/@exit>
#act
break
#ELSEACT
goto @领取AA
[@领取AA]
#if
CHECKBAGSIZE 3
#act
goto @领取AAA
break
#ELSESAY
\ \
您的包袱已满，请清理后再来领取奖励！！
[@领取AAA]
#if
check [151] 0
#act
mov S99 恭喜[%s]在闯天关中获得了
#say
<您幸运的获得了:/SCOLOR=242>
#if
check [151] 0
equal M0 0
#act
CHANGEEXP + <$STR(M9)>
INC S99 [经验:<$STR(M9)>]
#say
<经验:/SCOLOR=250><$STR(M9)>
#if
check [151] 0
equal M0 1
#act
give <$STR(S61)> 1
INC S99 [<$STR(S61)>]
#say
宝物：<$STR(S61)>
#if
check [151] 0
equal M0 2
#act
give <$STR(S61)> 1
INC S99 [<$STR(S61)>]
#say
宝物：<$STR(S61)>
#if
check [151] 0
equal M1 2
#act
give <$STR(S62)> 1
INC S99 ‖而且发现隐藏物品[<$STR(S62)>]
#say
<‖隐藏物品：/SCOLOR=253><$STR(S62)>
#if
check [151] 0
equal M2 2
#act
give <$STR(S63)> 1
INC S99 ‖并且找到了稀有物品[<$STR(S63)>]
#say
‖<稀有物品：/SCOLOR=254><$STR(S63)>
#if
check [151] 0
#act
set [151] 1
INC S99 !~~~,在庄园里换灵符进入闯天关！
SENDMSG 0 <$STR(S99)>
SendCenterMsg 246 229 <$STR(S99)> 1
#if
#say
\ \
<可能有更好的宝藏在下一关等着您哦~/SCOLOR=254>\
<您给我一张灵符，我可以直接带您进入下一关，您是否愿意？/SCOLOR=253> \ \
<是的进入下一关/@下一关> <不。我要回天庭/@回天庭>\
[@下一关]
#IF
CHECKGAMEGIRD > 0
#ACT
GAMEGIRD - 1
mov S78 0
MOV S61 0
MOV S62 0
MOV S63 0
MOV S64 0
MOV S65 0
MOV S66 0
MOV M0 0
MOV M1 0
MOV M2 0
MOV M3 0
MOV M4 0
MOV M5 0
MOV M9 0
CLEARMAPMON <$MAPCODE>
;是否任务中
set [150] 0
;是否已查看过宝物
set [152] 0
;是否领取过奖励
set [151] 0
mapmove D5071A 11 12
SENDMSG 7 灵符数量减(1),你当前的灵符数量为<$GAMEGIRD>张！
#ELSESAY
\ \
<你给我的灵符在哪呢？要不你先去兑换一些？/AUTOCOLOR=254,251,168,191,250,19,245,253>\ \
<回庄园兑换灵符后再来找我吧/@回天庭>\
[@回天庭]
#ACT
mapmove m101A 19 31
}
